It is possible to model a resistor as a capacitor and switch combination. The value of the equivalent is proportional to the frequency of the switch divided by the capacitance.
Construct a filter from MOSFETs and capacitors where the filter characteristics are a function of the switching frequency of the MOSFETs.
In order to quickly determine the filter characteristics, use ideal switches (voltage controlled resistors) instead of MOSFETs. The resulting simulation speedup can be as great as 7 to 10 times faster than a circuit using MOSFETs.
The model constructs an RC network using a resistor and a capacitor along with a switched capacitor equivalent network. Node RCOUT is the resistor/capacitor output, and VCROUT is the switched capacitor output.
The switches GVCR1 and GVCR2, together with the capacitance C3, model the resistor. The resistor value is calculated as:
where Tswitch is the period of the pulses PHI1 and PHI2.
*FILE:VCR1.SP A SWITCHED CAPACITOR RC CIRCUIT
.OPTIONS acct NOMOD POST
.IC V(SW1)=0 V(RCOUT)=0 V(VCROUT)=0
.TRAN 5U 200U
.GRAPH RC=V(RCOUT) SWITCH=V(VCROUT) (0,5)
VCC VCC GND 5V
C RCOUT GND 1NF
R VCC RCOUT 25K
C6 VCROUT GND 1NF
* equivalent circuit for 25k resistor r=12.5us/.5nf
VA PHI1 GND PULSE 0 5 1US .5US .5US 3US 12.5US
VB PHI2 GND PULSE 0 5 7US .5US .5US 3US 12.5US
GVCR1 VCC SW1 PHI1 GND LEVEL=1 MIN=100 MAX=1MEG 1.MEG -.5MEG
GVCR2 SW1 VCROUT PHI2 GND LEVEL=1 MIN=100 MAX=1MEG 1.MEG .5MEG
C3 SW1 GND .5NF
.END
This example is a fifth order elliptic switched capacitor filter with passband 0-1 kHz, loss less than 0.05 dB. It is realized by cascading linear, high_Q biquad, and low_Q biquad sections. The G Element models the switches with a resistance of 1 ohm when the switch is closed and 100 Megohm when it is open. The E Element models op-amps as an ideal op-amp. The transient response of the filter is provided for 1 kHz and 2 kHz sinusoidal input signalGregorian, Roubik & Temes, Gabor C. Analog MOS Integrated Circuits. J. Wiley, 1986, page 354..
SWCAP5.SP Fifth Order Elliptic Switched Capacitor Filter.
.OPTIONS POST PROBE
.GLOBAL phi1 phi2
.TRAN 2u 3.2m UIC
*.GRAPH v(phi1) v(phi2) V(in)
.PROBE V(out)
*.PLOT v(in) v(phi1) v(phi2) v(out
*Iin 0 in SIN(0,1ma,1.0khz)
Iin 0 in SIN(0,1v,2khz)
Vphi1 phi1 0 PULSE(0,2 00u,.5u,.5u,7u,20u)
Vphi2 phi2 0 PULSE(0,2 10u,.5u,.5u,7u,20u)
Rsrc in 0 1k
Rload out 0 1k
Xsh in out1 sh
Xlin out1 out2 linear
Xhq out2 out3 hqbiq
Xlq out3 out lqbiq
.SUBCKT sh in out
Gs1 in 1 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Eop1 out 0 OPAMP 1 out
Ch 1 0 1.0pf
.ENDS
.SUBCKT linear in out
Gs1 in 1 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs2 1 0 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Cs 1 2 1.0pf
Gs3 2 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs4 2 3 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Eop1 out 0 OPAMP 0 3
Ce out 3 9.6725pf
Gs5 out 4 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs6 4 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Cd 4 2 1.0pf
Csh in 3 0.5pf
.ENDS
.SUBCKT hqbiq in out
Gs1 in 1 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs2 1 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
C1 1 2 0.5pf
Gs3 2 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs4 2 3 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Eop1 4 0 OPAMP 0 3
Ca 3 4 7.072pf
Gs5 4 5 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs6 5 0 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
C3 5 6 0.59075pf
Gs7 6 7 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs8 6 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Eop2 out 0 OPAMP 0 7
Cb 7 out 4.3733pf
Gs9 out 8 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs10 8 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
C4 out 3 1.6518pf
C2 8 2 0.9963pf
C11 7 in 0.5pf
.ENDS
.SUBCKT lqbiq in out
Gs1 in 1 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs2 1 2 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
C1 2 3 0.9963pf
Gs3 2 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs4 3 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs5 3 4 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Ca 4 5 8.833pf
Eop1 5 0 OPAMP 0 4
Gs6 5 6 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Gs7 6 0 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
C3 6 7 1.0558pf
Gs8 7 8 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs9 7 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
Eop2 9 0 OPAMP 0 8
Cb 8 9 3.8643pf
Gs10 9 10 VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
Gs11 10 0 VCR PWL(1) phi1 0 0.5v,100meg 1.0v,1.0
C4 10 7 0.5pf
C2 10 3 0.5pf
C11 8 1 3.15425pf
Gs12 9 out VCR PWL(1) phi2 0 0.5v,100meg 1.0v,1.0
.ENDS
.END
References for this chapter are listed below.
1. Williams, Arthur B., and Taylor, Fred J. Electronic Filter Design Handbook . New York: McGraw-Hill, 1988, pp. 6-20 to 6-23.
2. Nillson, James W. Electric Circuits, 4th Edition. Reading, Massachusetts: Addison-Wesley, 1993.
3. Edminister, Joseph A. Electric Circuits. New York: McGraw-Hill, 1965.
4. Ghausi, Kelly, and M.S. On the Effective Dominant Pole of the Distributed RC Networks . Jour. Franklin Inst ., June 1965, pp. 417- 429.
5. Elmore, W.C. and Sands, M. Electronics, National Nuclear Energy Series, New York: McGraw-Hill, 1949.
6. Pillage, L.T. and Rohrer, R.A. Asymptotic Waveform Evaluation for Timing Analysis , IEEE Trans. CAD , Apr. 1990, pp. 352 - 366.
7. Kuo, F. F. Network Analysis and Synthesis. John Wiley and Sons, 1966.
8. Gregorian, Roubik & Temes, Gabor C. Analog MOS Integrated Circuits. J. Wiley, 1986, page 354.
Star-Hspice Manual - Release 2001.2 - June 2001
