Using the VBIC Bipolar Transistor Model

The VBIC (Vertical Bipolar Inter-Company) model is a new bipolar transistor model for Star-Hspice. You can use VBIC by specifying parameter LEVEL=4 for the bipolar transistor model.

VBIC addresses many problems of the SPICE Gummel-Poon model:

• More accurate modeling of Early effect
• Parasitic substrate transistor
• Modulation of collector resistance
• Avalanche multiplication in collector junction, parasitic capacitances of base-emitter overlap in double poly BJTs, and self heating.

Understanding the History of VBIC

VBIC was developed by engineers at several companies. The detailed equations1 for all elements are given in the referenced publication. Recent information and source code can be found on the web site:

http://www-sm.rz.fht-esslingen.de/institute/iafgp/neu/VBIC/index.html

Our implementation is compliant to standard VBIC. Self-heating and excess phases have been implemented or enabled in this version 99.4

The large signal equivalent circuit for VBIC is shown in Transient Analysis. Capacitors CBCO, CBEO and resistors RCX, RBX, RE, and RS are linear elements, all other elements of the equivalent circuit are nonlinear.

VBIC Parameters

Default Model Parameters for BJT, LEVEL 4 lists the parameters for the model that you can set. Default Model Parameters for BJT, LEVEL 4 also contains the default values for the parameters. The same parameter names are used in the table and the previous referenced publication.

Figure 16-14: Transient Analysis

If values of parameters given by the user are beyond their ranges, those parameters will be reset to new values and warnings will be printed unless the option NOWARN is set.

Noise Analysis

The following sources of noise are taken into account:

• The thermal noise of resistors RBX, RCX, RE, RS, RBP, RCI, RBI
• Shot noise of currents IBE, IBEP, ICC, ICCP
• Flicker noise due to currents IBE, IBEP

The noise due to IBEX and IGC is not included in this preliminary version (nor in the standard VBIC), but will be included in the next release.

Accounting for Self-heating and excess phase

After self-heating effect is accounted for, the device element syntax becomes:

Qxxx nc nb ne <ns> <nT> mname <regular parameters> <tnodeout>

where nT is the node for temperature. If this node is given, but ns is not given, the flag "tnodeout" must be specified to indicate the fourth node is temperature node instead of substrate node. To turn on self-heating, in addition to giving the T node, the model parameter Rth must be not zero in the model card.

Excess phase has only effects on ac and transient characteristics analysis. To turn on this effect, the model parameter TD must be non-zero. But for transient analysis, to turn on excess phase is not recommended due to model's convergence very sensitive to TD value.

Example

Example with no self-heating effect.

Usage:

Q1 21 22 22 22 VBIC <parameters>

.MODEL VBIC NPN <parameters>

Complete netlist:

*VBIC example, DC analysis

.OPTIONS NODE POST NOPAGE

.WIDTH OUT=80

.DC QVcolem 0 5 0.1 SWEEP QVbasem 0.7 0.86 0.05

.TEMP -20.0 +25. +100.

.PRINT DC I1(Q1) I2(Q1) I3(Q1) I4(Q1)

.PRINT DC V(102) V(202)

Vbas 101 0 QVbasem

Vcol 102 0 QVcolem

Vsub 104 0 0.

Vemi 103 0 0.

R1 101 201 10

R2 102 202 10

R4 104 204 10

R3 103 203 10

Q1 202 201 203 204 VBIC_EXAMPLE

.model VBIC_EXAMPLE npn LEVEL=4

+ afn=1 ajc=-0.5 aje=0.5 ajs=0.5

+ avc1=0 avc2=0 bfn=1 cbco=0 cbeo=0 cjc=2e-14

+ cjcp=4e-13 cje=le-13 cjep=le-13 cth=0

+ ea=1.12 eaic=1.12 eaie=1.12 eais=1.12 eanc=1.12

+ eane=1.12 eans=1.12 fc=0.9 gamm=2e-11 hrcf=2

+ ibci=2e-17 ibcip=0 ibcn=5e-15 ibcnp=0

+ ibei=1e-18 ibeip=0 iben=5e-15 ibenp=0

+ ikf=2e-3 ikp=2e-4 ikr=2e-4 is=le-16 isp=le-15 itf=8e-2

+ kfn=0 mc=0.33 me=0.33 ms=0.33

+ nci=1 ncip=1 ncn=2 ncnp=2 nei=1 nen=2

+ nf=1 nfp=1 nr=1 pc=0.75 pe=0.75 ps=0.75 qco=le-12 qtf=0

+ rbi=4 rbp=4 rbx=1 rci=6 rcx=1 re=0.2 rs=2

+ rth=300 tavc=0 td=2e-11 tf=10e-12 tnf=0 tr=100e-12

+ tnom=25 tref=25 vef=10 ver=4 vo=2

+ vtf=0 wbe=1 wsp=1

+ xii=3 xin=3 xis=3 xrb=0 xrc=0 xre=0 xrs=0 xtf=20 xvo=0

*.END

Example with self-heating effects.

*# VERSION: 99.4

.option absmos=1e-12 relmos=1e-6 relv=1e-6 absv=1e-9

vc c 0 0

vb b 0 0

ve e 0 0

vs s 0 0

vc1 c1 c 0

vb1 b1 b 0

ve1 e1 e 0

vs1 s1 s 0

*vt t 0 1meg

.temp 27

Q1 c1 b1 e1 s1 t mod1 area=1 tnodeout

.model mod1 npn LEVEL=4

+ Tnom=27 RCX=10 RCI=60 VO=2 GAMM=2.e-11

+ HRCF=2 RBX=10 RBI=40 RE=2

+ RS=20 RBP=40 IS=1e-16 NF=1.00000e+00

+ NR=1.00000e+00 FC=9.00000e-01 CBEO=0

+ CJE=1.e-13 PE=0.75 ME=0.33

+ AJE=-5.00000e-01 CBCO=0 CJC=2e-14

+ QCO=1e-12 CJEP=1e-13 PC=7.50000e-01

+ MC=3.30000e-01 AJC=-5.00000e-01 CJCP=4e-13

+ PS=7.50000e-01 MS=3.30000e-01 AJS=-5.00000e-01

+ IBEI=1e-18 WBE=1.0000 NEI=1.00000e+00

+ IBEN=5e-15 NEN=2.00000e+00 IBCI=2e-17

+ NCI=1.00000e+00 IBCN=5e-15 NCN=2.00000e+00

+ AVC1=2 AVC2=15 ISP=1e-15

+ WSP=1.000e+00 NFP=1.00000e+00 IBEIP=0

+ IBENP=0 IBCIP=0 NCIP=1.00000e+00

+ IBCNP=0 NCNP=2.00000e+00 VEF=10

+ VER=4 IKF=0.002 IKR=0.0002 IKP=0.0002

+ TF=1.e-11 QTF=0 XTF=20

+ VTF=0 ITF=0.08 TR=1e-10

+ KFN=0 AFN=1.0e+00

+ BFN=1.0000e+00 XRE=0 XRB=0

+ XRC=0 XRS=0 XVO=0

+ EA=1.12000e+00 EAIE=1.12000e+00

+ EANE=1.12000e+00 EANC=1.12000e+00

+ EANS=1.12000e+00 XIS=3.00000e+00

+ XII=3.00000e+00 XIN=3.00000e+00

+ TNF=0 TAVC=0

+ RTH=300 CTH=0

+ TD=0

*+ TD=2.e-11

.dc vc 0.0 5.0001 0.05 vb 0.7 1.0001 0.05

.print i(vc) i(vb) v(t)

.end

where v(t) print out the device temperature using T node.

Notes on Using VBIC

1. Set LEVEL to 4 to identify the model as a VBIC bipolar junction transistor model.

2. The LEVEL 4 model does not scale with any area terms, and does not yet scale with M.

3. Setting these parameters to zero infers a value of infinity: HRCF, IKF, IKP, IKR, ITF, VEF, VER, VO, VTF.

4. Parameters CBC0, CBE0, QC0, TNOM, V0, and XV0 are aliases for CBCO, CBEO, QCO, TREF, VO, and XVO, respectively. Avant! discourages use of TNOM as a model parameter name as it is used as the name of the default room temperature in Star-Hspice.

5. The default room temperature is 25 degrees in Star-Hspice, but is 27 in some other simulators. If the VBIC bipolar junction transistor model parameters are specified at 27 degrees, TREF=27 should be added to the model, so that the model parameters will be interpreted correctly. It is a matter of choice whether or not to set the nominal simulation temperature to 27, by adding .OPTION TNOM=27 to the netlist. This should be done when testing Star-Hspice versus other simulators that use 27 as the default room temperature.

6. Pole-zero simulation of this model is not supported.

7. For this version of implementation, all seven internal resistors should have values greater than or equal to 1.0e -3 . Values smaller than this will be reassigned a value of 1.0e -3.