Signal Detection Test Circuit

This example is a high frequency mixer test circuit, illustrating the effect of using a window to detect a weak signal in the presence of a strong signal at a nearby frequency. Two high frequency signals are added that have a 40 dB separation (that is, amplitudes are 1.0 and 0.01).

Input Listing

Signal Detection Test Circuit For FFT

v1 1 0 sin(0 1 1470.2Meg 0 0 90)

r1 1 0 1

v2 2 0 sin(0 0.01 1560.25Meg 0 0 90)

r2 2 0 1

E1 3 0 vol='v(1)+v(2)'

r3 3 0 1

.tran 0.1n 102.4n

.option post probe

.fft v(3)

.fft v(3) window=Bartlett fmin=1.2g fmax=2.2g

.fft v(3) window=hanning fmin=1.2g fmax=2.2g

.fft v(3) window=hamminn fmin=1.2g fmax=2.2g

.fft v(3) window=blackman fmin=1.2g fmax=2.2g

.fft v(3) window=harris fmin=1.2g fmax=2.2g

.fft v(3) window=gaussian fmin=1.2g fmax=2.2g

.fft v(3) window=kaiser fmin=1.2g fmax=2.2g

.end

For comparison with the rectangular window in Mixer Output Spectrum, Rectangular Window, the spectra of the output for all of the FFT window types are shown in Figures Mixer Output Spectrum, Bartlett Window through
Mixer Output Spectrum, Kaiser-Bessel Window. Without windowing, the weak signal is essentially undetectable due to spectral leakage.

Figure 28-15: Mixer Output Spectrum, Rectangular Window

In the Bartlett window in Mixer Output Spectrum, Bartlett Window, notice the dramatic decrease in the noise floor over the rectangular window (from -55 to more than -90 dB). The cosine windows (Hanning, Hamming, Blackman, and Blackman-Harris) all produce better results than the Bartlett window. However, the degree of separation of the two tones and the noise floor is best with the Blackman-Harris window. The final two windows (Figures Mixer Output Spectrum, Gaussian Window and Mixer Output Spectrum, Kaiser-Bessel Window) are parameterized with ALFA=3.0, which is the default value in Star-Hspice. These two windows also produce acceptable results, especially the Kaiser-Bessel window, which gives sharp separation of the two tones and almost a -100-dB noise floor.

Such processing of high frequencies, as demonstrated in this example, shows the numerical stability and accuracy of the FFT spectrum analysis algorithms in Star-Hspice.

Figure 28-16: Mixer Output Spectrum, Bartlett Window

Figure 28-17: Mixer Output Spectrum, Hanning Window

Figure 28-18: Mixer Output Spectrum, Hamming Window

Figure 28-19: Mixer Output Spectrum, Blackman Window

Figure 28-20: Mixer Output Spectrum, Blackman-Harris Window

Figure 28-21: Mixer Output Spectrum, Gaussian Window

Figure 28-22: Mixer Output Spectrum, Kaiser-Bessel Window

References

1. For an excellent discussion of DFT windows, see Fredric J. Harris, "On the Use of Windows for Harmonic Analysis with Discrete Fourier Transform", Proceedings of the IEEE , Vol. 66, No. 1, Jan. 1978.