Using the W Element

The W Element, multiconductor lossy frequency-dependent transmission line, provides advanced modeling capabilities for transmission lines.

The W Element provides:

Figure 18-5: Spurious Ringing in U Element

The W Element supports the analyses:

Using Time-Step Control

The W Element provides accurate results with just 1-2 time steps per excitation transient (0.1 ns in the above example). It supports Star-Hspice's iteration count (the option LVLTIM =0) and DVDT ( LVLTIM =1 or 3) time step control algorithms. It does not support the LTE ( LVLTIM =2) algorithm yet. Star-Hspice's default time-step control algorithm is DVDT .

The W Element limits the maximum time step by the smallest transmission line delay in the circuit.

The W Element supports the TLINLIMIT option like the T Element. The default value of TLINLIMIT =0 enables special breakpoint building that improves transient accuracy for short lines, but reduces efficiency. To disable this special breakpoint building, set TLINLIMIT =1.

For longer transmission lines, there could be prolonged time intervals when nothing happens at the terminals when the wave propagates along the line. Star-Hspice increases the time step, and when the wave finally reaches the terminal, it decreases the accuracy of simulation. To prevent this, for longer lines excited with short pulses, set the .option DELMAX to limit the time step to 0.5-1 of the excitation transient.

.OPTION RISETIME

The . OPTION RISETIME used by U Elements to compute the number of lumped segments, also affects the transient simulation of W Elements with frequency-dependent parameters. It has no effect on AC analysis and W Elements with constant parameters (R s = G d = 0).

The option overrides W Element's internal frequency-range control, and should only be used for longer (over 10 m) cables. Setting RISETIME to a smaller value than the actual value of the excitation transient, decreases simulation accuracy.

W Element and Field Solver Updates

Accuracy Improvements for W Element

Accuracy has been improved for:

Field Solver Bug Fix

A slight accuracy problem with the Star-Hspice internal field solver for the case with both top and bottom ground planes has been discovered and fixed.

Dielectric Loss Modeling

New modeling equations have been implemented to address two issues:

1. Inaccurate dielectric loss.

2. The linear dependency at the high frequency region, causing undesirable effects.

To remedy these issues a new cutoff frequency for the Gd term is introduced as follows:

 

The default value of fgd is 0. You can specify an alternate value in the W Element statement:

Wxxx i1 i2 ... iN iR o1 o2 ... oN oR N=val L=val fgd=val

If you prefer to use the previous linear dependency, set fgd to 0.

.OPTION RISETIME Setting

The RISETIME parameter is used to compute the maximum frequency range for the transient analysis of W Element. Depending on its value, the following scheme is employed to determine the maximum frequency of interest:

Imaginary Term Handling for the Skin-Effect

As of the 1999.4 release of Star-Hspice, to depict the correct frequency response at high frequency, the imaginary term of the skin-effect has been added, and the resulting modeling equation for the frequency dependent resistance is given by:

 

However, for low frequency applications, this may cause significant errors and this imaginary term can optionally be excluded from the W Element statement:

Wxxx i1 i2 ... iN iR o1 o2 ... oN oR N=val L=val INCLUDERSIMAG=NO

W Element Transmission Line Properties Inputs

The W Element supports four different formats to input transmission line properties:

Syntax

The syntax of the W Element statement is:

Wxxx i1 i2 ... iN iR o1 o2 ... oN oR N=val L=val
+ <FSMODEL=name or RLGCMODEL=name or RLGCFILE=name or
+ UMODEL=name>	 			
+ <INCLUDERSIMAG=YES|NO> <FGD=val>
 

N

Number of signal conductors (excluding the reference conductor)

i1...iN

Nodes for the near-end signal-conductor terminal (see Terminal Node Numbering)

iR

Nodes for the near-end reference-conductor terminal (should be the same node as oR )

o1...oN

Nodes for the far-end signal-conductor terminal

oR

Nodes for the far-end reference-conductor terminal

L

Length of a transmission line

RLGCMODEL

Name of the RLGC model

FSMODEL

Name of the field-solver model

RLGCFILE

Name of the external file with RLGC parameters (see Input Model 4: W Element RLGC File)

UMODEL

Name of U .MODEL (see Input Model 2: U Model).

INCLUDERSIMAG

Specifies the imaginary term of the skin effect to be considered. The default value is YES. (see Using Frequency-Dependent Resistance and Conductance Matrices).

FGD

Specifies the cut-off frequency of dielectric loss. (see Dielectric Loss Modeling).

 

Figure 18-6: Terminal Node Numbering

You can specify parameters in the W Element card in any order. Specify the number of signal conductors, N, after the list of nodes. You can intermix the nodes and parameters in the W Element card.

You can specify only one RLGCmodel , FSmodel , Umodel , or RLGCfile in a single W Element card.

Input Model 1: W Element RLGC Model

The section, Using Transmission Line Equations and Parameters describes the W Element inputs R, L, G, C, R s (skin-effect), and G d (dielectric-loss) per-unit-length matrices. There are no limitations on the number of coupled conductors, shape of the matrices, line loss, length or amount of frequency dependence. The RLGC text file contains frequency-dependent RLGC matrices per unit length.

The W Element also handles frequency-independent (RLGC) and lossless (LC) lines. It does not support RC lines.

Since RLGC matrices are symmetric, only the lower-triangular parts of the matrices are specified in the RLGC model. The syntax of W Element RLGC model is:

.MODEL name W MODELTYPE=RLGC N=val Lo=matrix_entries
+ Co=matrix_entries [ Ro=matrix_entries Go=matrix_entries
+ Rs=matrix_entries Gd=matrix_entries Rognd=val Rsgnd=val
+ Lgnd=val ]

N

Number of signal conductors (same as that in the element card)

L

DC inductance matrix per unit length

C

DC capacitance matrix per unit length

Optional Parameters (default values are zero)

Ro

DC resistance matrix per unit length

 

Go

DC shunt conductance matrix per unit length

 

Rs

Skin-effect resistance matrix per unit length

 

Gd

Dielectric-loss conductance matrix per unit length

 

Lgnd

DC inductance matrix per unit length for grounds (reference line)

 

Rognd

DC resistance matrix per unit length for grounds

 

Rsgnd

Skin-effect resistance matrix per unit length for grounds

 

Example

The following is example.sp input netlist file showing the RLGC file input usage of the W Element:

* W-Element example, four-conductor line
W1 N=3 1 3 5 0 2 4 6 0 RLGCMODEL=example_rlc l=0.97
V1 1 0 AC=1v DC=0v pulse(4.82v 0v 5ns 0.1ns 0.1ns 25ns).AC lin 1000 0Hz 1GHz
.DC v1 0v 5v 0.1v
.tran 0.1ns 200ns
* RLGC matrices for a four-conductor lossy
.MODEL example_rlc W MODELTYPE=RLGC N=3
+ Lo=
+ 2.311e-6
+ 4.14e-7 2.988e-6
+ 8.42e-8 5.27e-7 2.813e-6
+ Co=
+ 2.392e-11
+ -5.41e-12 2.123e-11
+ -1.08e-12 -5.72e-12 2.447e-11
+ Ro=
+ 42.5
+ 0 41.0
+ 0 0 33.5
+ Go=
+ 0.000609
+ -0.0001419 0.000599
+ -0.00002323 -0.00009 0.000502
+ Rs=
+ 0.00135
+ 0 0.001303
+ 0 0 0.001064
+ Gd=
+ 5.242e-13
+ -1.221e-13 5.164e-13
+ -1.999e-14 -7.747e-14 4.321e-13
.end

Star-Hspice Simulation Results shows a plot of Star-Hspice simulation results (a) DC Sweep, b) AC response, and c) transient waveforms). It shows that the transmission-line behavior of interconnects has significant and complicated effect on the signal integrity, and accurate transmission line modeling is necessary for verification of high-speed designs.

 

Figure 18-7: Star-Hspice Simulation Results

(a) DC Sweep

(b) AC Response

 

(c) Transient Waveforms

Input Model 2: U Model

The W Element accepts the U model as an input thus providing backward compatibility with the U Element, and taking advantage of the U model's geometric and measured-parameter interfaces.

To use the W Element with the U model, specify Umodel=U-model_name on the W Element card.

The W Element supports all U-model modes, including:

The only exception is Llev =1, which adds the second ground plane to the U model, and is not supported by the W Element. To model the extra ground plane, add an extra conductor to the W Element in Elev =2, or use an external lumped capacitor in Elev =1 and 3. See Ideal and Lumped Transmission Lines, for information on the U model.

Using RLGC Matrices

RLGC matrices in the W Element's RLGC file are in the Maxwellian format. In the U model, they are in self/mutual format (see Determining Matrix Properties for conversion information). When using the U model, the W Element performs the conversion internally. RLGC Matrices in W Element and U Model shows how the U-model's RLGC matrices are related to the W Element's RLGC matrices, and how they are used by the W Element.

Handling the Dielectric-loss Matrix

Since the U model does not input the dielectric loss matrix Gd, the W Element defaults Gd to zero when it uses the U-model input. In future Star-Hspice releases, the W Element will have its own .MODEL with Gd capability. For this release, use RLGC file to specify nonzero Gd.

Handling the Skin-effect Matrix

The skin-effect resistance R s is used differently by U and W Elements. In a W Element, the R s matrix specifies the square-root dependence of the frequency-dependent resistance,

 

In a U Element, R is the value of skin resistance at the frequency:

 

where the core resistance R c is equivalent to the W Element's DC resistance R o . The frequency at which U Element computes R s is:

 

Table 18-1: RLGC Matrices in W Element and U Model

W Element Parameters U Model Parameters

L, C

G o , G d

Nlay =1 (no skin effect) Nlay =2 (skin effect present)

R o

Nlay =1 (no skin effect) Nlay =2 (skin effect present)

R s

If you do not specify the RISETIME option, the U Element uses Tstep from the . tran card.

 

For U models with

W Element

RLGC input; Elev =2

Uses R s values you specify in the U model.

Geometric input; Elev =1

Divides the R s computed internally by the U model, and divides it by to obtain the R s.

For Elev =1, the value of R s in the U model printout is not be the same as R s actually used by the W Element.

Measured-parameter input; Elev =3

Does not support skin effect.

Example

The following Star-Hspice netlist is for a 4-conductor line shown in
4-Conductor Line.

* W Element example, four-conductor line, U model
W1 1 3 5 0 2 4 6 0 Umodel=example N=3 l=0.97
.MODEL example U LEVEL=3 NL=3 Elev=2 Llev=0 Plev=1 Nlay=2
+
+ L11=2.311uH
+ L12=0.414uH L22=2.988uH
+ L13=84.2nH L23=0.527uH L33=2.813uH
+
+ Cr1=17.43pF
+ C12=5.41pF Cr2=10.1pF
+ C13=1.08pF C23=5.72pF Cr3=17.67pF
+
+ R1c=42.5 R2c=41.0 R3c=33.5
+
+ Gr1=0.44387mS
+ G12=0.1419mS Gr2=0.3671mS
+ G13=23.23uS G23=90uS Gr3=0.38877mS
+
+ R1s=0.00135 R2s=0.001303 R3s=0.001064
V1 1 0 AC=1v DC=0v pulse(4.82v 0v 5ns 0.1ns 0.1ns 25ns)
.AC lin 1000 0Hz 1GHz
.DC v1 0v 5v 0.1v
.TRAN 0.1ns 200ns
.END

Figure 18-8: 4-Conductor Line

Input Model 3: Field-Solver Model

Instead of RLGC matrices, you can directly use geometric data with the W Element using a new built-in field solver in Star-Hspice. To use the W Element with a field solver, specify FSmodel=model_name on the W Element card. The Star-Hspice field solver is described in Extracting Transmission Line Parameters.

Input Model 4: W Element RLGC File

RLGC matrices can also be specified in an external file (RLGC file). This external file format is more restricted than the RLGC model; for example, it cannot be parameterized and does not support the ground inductance and resistance. This format does not provides any advantage over the RLGC model and should not be used. (It is supported for the backward compatibility purpose only.)

Similar to the RLGC model, only the lower-triangular parts of the matrices are specified in the RLGC file. However, unlike the RLGC model, the RLGC file is order-dependent. The parameters in the RLGC file are in the following order:

 

N

Number of signal conductors (same as that in the element card)

L

DC inductance matrix per unit length

C

DC capacitance matrix per unit length

Optional Parameters

R o

DC resistance matrix per unit length

G o

DC shunt conductance matrix per unit length

R s

Skin-effect resistance matrix per unit length

G d

Dielectric-loss conductance matrix per unit length


NOTE: You can skip optional parameters (they default to zero). But if you specify one of the optional parameters, you must specify all preceding parameters even if they are zero.
Comments and Separators

An asterisk `*' comments out everything until the end of its line. You can separate numbers using any of the characters: space, tab, newline, `,', `;', `(`, `)', `[`, `]', `{` or `}'.

Example

The netlist example used for the RLGC model in the previous section is rewritten using RLGC file below:

* W- Element example, four-conductor line
W1 N=3 1 3 5 0 2 4 6 0 RLGCfile=example.rlc l=0.97
V1 1 0 AC=1v DC=0v pulse(4.82v 0v 5ns 0.1ns 0.1ns 25ns).AC lin 1000 0Hz 1GHz
.DC v1 0v 5v 0.1v
.tran 0.1ns 200ns
.end

This calls the following example.rlc RLGC file:

* RLGC parameters for a four-conductor lossy
* frequency-dependent line
* N (number of signal conductors)
3
* Lo
2.311e-6
4.14e-7 2.988e-6
8.42e-8 5.27e-7 2.813e-6
* Co
2.392e-11
-5.41e-12 2.123e-11
-1.08e-12 -5.72e-12 2.447e-11
* Ro
42.5
0 41.0
0 0 33.5
* Go
0.000609
-0.0001419 0.000599
-0.00002323 -0.00009 0.000502
* Rs
0.00135
0 0.001303
0 0 0.001064
* Gd
5.242e-13
-1.221e-13 5.164e-13
-1.999e-14 -7.747e-14 4.321e-13

The RLGC file does not support Star-Hspice scale suffices such as n (10 -9 ) or p (10 -12 ).

Star-Hspice Manual - Release 2001.2 - June 2001