Active Elements

Diode Element

The general syntax for including a diode element in a Star-Hspice netlist is:

Geometric (LEVEL = 1) and Non-geometric (LEVEL = 3) form:

Dxxx nplus nminus mname <<AREA = >area> <<PJ = >val> <WP = val>
+ <LP = val> <WM = val> <LM = val> <OFF> <IC = vd> <M = val>
+ <DTEMP = val>

or

Dxxx nplus nminus mname <W = width> <L = length> <WP = val>
+ <LP = val> <WM = val> <LM = val> <OFF> <IC = vd> <M = val>
+ <DTEMP = val>

Fowler-Nordheim (LEVEL = 2) form:

Dxxx nplus nminus mname <W = val <L = val>> <WP = val> <OFF>
+ <IC = vd> <M = val>

The only required fields are the two nodes and the model name. If the parameter labels are used, the optional arguments may come in any order, although the nodes and model name must come first.

The arguments are as follows:

Dxxx	Diode element name. Must begin with "D", which can be followed by up to 1023 alphanumeric characters.
nplus	Positive terminal (anode) node name. The series resistor of the equivalent circuit is attached to this terminal.
nminus	Negative terminal (cathode) node name
mname	Diode model name reference
AREA	Area of the diode (unitless for diode model LEVEL = 1 and square meters for diode model LEVEL = 3). This affects saturation currents, capacitances and resistances (diode model parameters IK, IKR, JS, CJO and RS). Area factor for diode model LEVEL = 1 is not affected by the SCALE option. Default = 1.0. Overrides AREA from the diode model. If unspecified, is calculated from width and length specifications.
PJ	Periphery of junction (unitless for diode model LEVEL = 1 and meters for diode model LEVEL = 3). Overrides PJ from the diode model. If unspecified, calculated from the width and length specifications.
WP	Width of polysilicon capacitor in meters (for diode model LEVEL = 3 only). Overrides WP in diode model. Default = 0.0.
LP	Length of polysilicon capacitor in meters (for diode model LEVEL = 3 only). Overrides LP in diode model. Default = 0.0.
WM	Width of metal capacitor in meters (for diode model LEVEL = 3 only). Overrides WM in diode model. Default = 0.0.
LM	Width of metal capacitor in meters (for diode model LEVEL = 3 only). Overrides LM in diode model. Default = 0.0.
OFF	Sets initial condition to OFF for this element in DC analysis. Default = ON.
IC = vd	Initial voltage across the diode element. This value is used when the UIC option is present in the .TRAN statement and is overridden by the .IC statement.
M	Multiplier to simulate multiple diodes in parallel. All currents, capacitances and resistances are affected by the setting of M. Default = 1.
DTEMP	The difference between the element temperature and the circuit temperature in Celsius. Default = 0.0.
W	Width of the diode in meters (diode model LEVEL=3 only)
L	Length of the diode in meters (diode model LEVEL = 3 only)

Example

Diode D1 with anode and cathode connected to nodes 1 and 2 where the diode model is given by diode1.

D1 1 2 diode1

Diode Dprot with anode and cathode connected to node output and ground references diode model firstd and specifies an area of 10 (unitless for LEVEL = 1 model) with the diode OFF as an initial condition.

Dprot output gnd firstd 10 OFF

Diode Ddrive with anode and cathode connected to nodes driver and output with a width and length of 500 microns and references diode model model_d.

Ddrive driver output model_d W = 5e-4 L = 5e-4 IC = 0.2

Bipolar Junction Transistors (BJTs) Element

The general syntax for including a BJT element in a Star-Hspice netlist is:

General form:

Qxxx nc nb ne <ns> mname <area> <OFF> <IC = vbeval,vceval>
+ <M = val> <DTEMP = val>

or

Qxxx nc nb ne <ns> mname <AREA = area> <AREAB = val>
+ <AREAC = val> <OFF> <VBE = vbeval> <VCE = vceval> <M = val>
+ <DTEMP = val>

The only required fields are the collector, base and emitter nodes, and the model name. The nodes and model name must come first.

The arguments are as follows:

Qxxx	BJT element name. Must begin with "Q", which can be followed by up to 1023 alphanumeric characters.
nc	Collector terminal node name
nb	Base terminal node name
ne	Emitter terminal node name
ns	Substrate terminal node name, which is optional. Can also be set in the BJT model with the parameter BULK.
mname	BJT model name reference
area, AREA = area	Emitter area multiplying factor which affects currents, resistances and capacitances. Default = 1.0.
OFF	Sets initial condition to OFF for this element in DC analysis. Default = ON.
IC = vbeval, vceval, VBE, VCE	Initial internal base-emitter voltage (vbeval) and collector-emitter voltage (vceval). These are used when UIC is present in the .TRAN statement and is overridden by the .IC statement.
M	Multiplier to simulate multiple BJTs in parallel. All currents, capacitances and resistances are affected by the setting of M. Default = 1.
DTEMP	The difference between the element temperature and the circuit temperature in Celsius. Default = 0.0.
AREAB	Base area multiplying factor that affects currents, resistances and capacitances. Default = AREA.
AREAC	Collector area multiplying factor that affects currents, resistances and capacitances. Default = AREA.

Example

BJT Q1 with collector, base, and emitter connected to nodes 1, 2 and 3 where the BJT model is given by model_1.

Q1 1 2 3 model_1

BJT Qopamp1 with collector, base, and emitter connected to nodes c1, b3 and e2 and the substrate connected to node s. The BJT model is given by 1stagepnp and the area factors AREA, AREAB and AREAC are 1.5, 2.5 and 3.0, respectively.

Qopamp1 c1 b3 e2 s 1stagepnp AREA = 1.5 AREAB = 2.5 AREAC = 3.0

BJT Qdrive with collector, base, and emitter connected to nodes driver, in and output with an area factor of 0.1 and references BJT model model_npn.

Qdrive driver in output model_npn 0.1

JFETs and MESFETs

The general syntax for including a JFET or MESFET element in a Star-Hspice netlist is:

General form:

Jxxx nd ng ns <nb> mname <<<AREA> = area | <W = val> <L = val>>
+ <OFF> <IC = vdsval,vgsval> <M = val> <DTEMP = val>

or

Jxxx nd ng ns <nb> mname <<<AREA> = area> | <W = val> <L = val>>
+ <OFF> <VDS = vdsval> <VGS = vgsval> <M = val> <DTEMP = val>

The only required fields are the drain, gate and source nodes, and the model name. The nodes and model name must come first.

The arguments are as follows:

Jxxx	JFET or MESFET element name. Must begin with "J", which can be followed by up to 1023 alphanumeric characters.
nd	Drain terminal node name
ng	Gate terminal node name
ns	Source terminal node name
nb	Bulk terminal node name, which is optional.
mname	JFET or MESFET model name reference
area, AREA = area	Area multiplying factor that affects the BETA, RD, RS, IS, CGS and CGD model parameters. Default = 1.0 in units of square meters.
W	FET gate width in meters
L	FET gate length in meters
OFF	Sets initial condition to OFF for this element in DC analysis. Default = ON.
IC = vdsval, vgsval, VDS, VGS	Initial internal drain-source voltage (vdsval) and gate-source voltage (vgsval). These are used when UIC is present in the .TRAN statement and is overridden by the .IC statement.
M	Multiplier to simulate multiple JFETs or MESFETs in parallel. All currents, capacitances, and resistances are affected by the setting of M. Default = 1.
DTEMP	The difference between the element temperature and the circuit temperature in Celsius. Default = 0.0.

Example

JFET J1 with drain, source, and gate connected to nodes 1, 2 and 3 where the JFET model is given by model_1.

J1 1 2 3 model_1

JFET Jopamp1 with drain, gate, and source connected to nodes d1, g3 and s2 and the bulk connected to node b. The JFET model is given by 1stage and the area is given as 100 microns.

Jopamp1 d1 g3 s2 b 1stage AREA = 100u

JFET Jdrive with drain, gate, and source connected to nodes driver, in and output with a width and length of 10 microns and references JFET model model_jfet.

Jdrive driver in output model_jfet W = 10u L = 10u

MOSFETs

The general syntax for including a MOSFET element in a Star-Hspice netlist is:

General form:

Mxxx nd ng ns <nb> mname <<L = >length> <<W = >width> <AD = val>
+ <AS = val> <PD = val> <PS = val> <NRD = val> <NRS = val>
+ <RDC = val> <RSC = val> <OFF> <IC = vds,vgs,vbs> <M = val>
+ <DTEMP = val> <GEO = val> <DELVTO = val>

or

.OPTION WL

Mxxx nd ng ns <nb> mname <width> <length> <other options...>

The only required fields are the drain, gate and source nodes, and the model name. The nodes and model name must come first. The second syntax is used in conjunction with the .OPTION WL statement that allows exchanging the width and length options when no label is given.

The arguments are as follows:

Mxxx	MOSFET element name. Must begin with "M", which can be followed by up to 1023 alphanumeric characters.
nd	Drain terminal node name
ng	Gate terminal node name
ns	Source terminal node name
nb	Bulk terminal node name, which is optional. Can be set in MOSFET model using parameter BULK.
mname	MOSFET model name reference
L	MOSFET channel length in meters. This parameter overrides DEFL in an OPTIONS statement. Default = DEFL with a maximum of 0.1m.
W	MOSFET channel width in meters. This parameter overrides DEFW in an OPTIONS statement. Default = DEFW.
AD	Drain diffusion area. Overrides DEFAD in the OPTIONS statement. Default = DEFAD only when the MOSFET model parameter ACM = 0.
AS	Source diffusion area. Overrides DEFAS in the OPTIONS statement. Default = DEFAS only when the MOSFET model parameter ACM = 0.
PD	Perimeter of the drain junction, including the channel edge. Overrides DEFPD in the OPTIONS statement. Default = DEFAD when the MOSFET model parameter ACM = 0 or 1, and default = 0.0 when ACM = 2 or 3.
PS	Perimeter of the source junction, including the channel edge. Overrides DEFPS in the OPTIONS statement. Default = DEFAS when the MOSFET model parameter ACM = 0 or 1, and default = 0.0 when ACM = 2 or 3.
NRD	Number of squares of drain diffusion for resistance calculations. Overrides DEFNRD in the OPTIONS statement. Default = DEFNRD when the MOSFET model parameter ACM = 0 or 1, and default = 0.0 when ACM = 2 or 3.
NRS	Number of squares of source diffusion for resistance calculations. Overrides DEFNRS in the OPTIONS statement. Default = DEFNRS when the MOSFET model parameter ACM = 0 or 1, and default = 0.0 when ACM = 2 or 3.
RDC	Additional drain resistance due to contact resistance with units of ohms. This value overrides the RDC setting in the MOSFET model specification. Default = 0.0.
RSC	Additional source resistance due to contact resistance with units of ohms. This value overrides the RSC setting in the MOSFET model specification. Default = 0.0.
OFF	Sets initial condition to OFF for this element in DC analysis. Default = ON. Note: this command does not work for depletion devices.
IC = vds, vgs, vbs	Initial voltage across the external drain and source (vds), gate and source (vgs), and bulk and source terminals (vbs). These are used when UIC is present in the .TRAN statement and are overridden by the .IC statement.
M	Multiplier to simulate multiple MOSFETs in parallel. All channel widths, diode leakages, capacitances and resistances are affected by the setting of M. Default = 1.
DTEMP	The difference between the element temperature and the circuit temperature in Celsius. Default = 0.0.
GEO	Source/drain sharing selector for MOSFET model parameter value ACM = 3. Default = 0.0.
DELVTO	Zero-bias threshold voltage shift. Default = 0.0.

Example

MOSFET M1 with drain, gate, and source connected to nodes 1, 2 and 3 where the MOSFET model is given by model_1.

M1 1 2 3 model_1

MOSFET Mopamp1 with drain, gate, and source connected to and nodes d1, g3 and s2 and the bulk connected to node b. The MOSFET model is given by 1stage and the length and width of the gate are given as 2 and 10 microns, respectively.

Mopamp1 d1 g3 s2 b 1stage L = 2u W = 10u

MOSFET Mdrive with drain, gate, and source connected to nodes driver, in and output with a width and length of 3 and 0.25 microns, respectively. This device references MOSFET model bsim3v3 and specifies a temperature for the device that is 4 degrees Celsius above the circuit temperature.

Mdrive driver in output bsim3v3 W = 3u L = 0.25u DTEMP = 4.0

Star-Hspice Manual - Release 2001.2 - June 2001