Running the Temperature Coefficients Demo

SPICE-type simulators do not always automatically compensate for variations in temperature. The simulators make many assumptions that are not valid for all technologies. Star-Hspice has first-order and second-order temperature coefficients in many of the critical model parameters to assure accurate simulations. There are two methods to optimize these temperature coefficients.

The first method uses the DC sweep variable TEMP. All of the Star-Hspice analysis sweeps allow two sweep variables; one of these must be the optimize variable to do an optimization. Sweeping TEMP limits the component to a linear element such as resistor, inductor, or capacitor. The second method uses multiple components at different temperatures.

In the following example, demo file $installdir/demo/hspice/ciropt/opttemp.sp, three circuits of a voltage source and a resistor are simulated at -25, 0, and +25 °C from nominal using the DTEMP parameter for element delta temperatures. The resistors share a common model. Three temperatures are necessary to solve a second order equation. This simulation template can be easily extended to a transient simulation of nonlinear components, such as bipolar transistors, diodes, and FETs.

Some simulation shortcuts are used in this example. In the internal output templates for resistors, LV1 (resistor) is the conductance (reciprocal resistance) at the desired temperature, allowing the optimization to be done in the resistance domain. To optimize more complex elements, use the current or voltage domain with measured sweep data. Also, the error function is expecting a sweep on at least two points, requiring the data statement to have two duplicate points.

Optimized Temperature Coefficients Example Input File

*FILE OPTTEMP.SP   OPTIMIZE RESISTOR TC1 AND TC2 

v-25 1 0 1v

v0   2 0 1v

v+25 3 0 1v

r-25 1 0 rmod dtemp=-25

r0   2 0 rmod dtemp=0

r+25 3 0 rmod dtemp=25

.model rmod R res=1k tc1r=tc1r_opt tc2r=tc2r_opt

Optimization Section

.model optmod opt

.dc data=RES_TEMP optimize=opt1

+           results=r@temp1,r@temp2,r@temp3

+           model=optmod

.param tc1r_opt=opt1(.001,-.1,.1)

.param tc2r_opt=opt1(1u,-1m,1m)

.meas r@temp1 err2 par(R_meas_t1) par('1.0 / lv1(r-25)')

.meas r@temp2 err2 par(R_meas_t2) par('1.0 / lv1(r0) ')

.meas r@temp3 err2 par(R_meas_t3) par('1.0 / lv1(r+25) ')

* * Output section *

.dc data=RES_TEMP

.print 'r1_diff'=par('1.0/lv1(r-25)')

+      'r2_diff'=par('1.0/lv1(r0)  ')

+      'r3_diff'=par('1.0/lv1(r+25)')

.data RES_TEMP R_meas_t1 R_meas_t2 R_meas_t3

950 1000 1010

950 1000 1010

.enddata 

.end