Example

Below is a complete example of the netlist that contains an output buffer, transmission line, and input buffer.

A digital signal is supplied to the node nd_in . It is transmitted by the output buffer to a network, goes through a transmission line, is received by an input buffer, and transformed into digital form and available on node nd_out_of_in_1 . IBIS file at16245a.ibs resides in the directory .ibis, which is located in the directory from which Star-Hspice is run.

**********************************************************

* test for iob: output buffer -- transmission line --input buffer

**********************************************************

.option post probe

**********************************************************

* Analysis

**********************************************************

.tran 0.05n 20n

**********************************************************

* Stimuli

**********************************************************

V_in nd_in 0 1V pulse ( 0V 1V 1n 1n 1n 4n 10n )

**********************************************************

* Output

**********************************************************

.print tran v(nd_pu) v(nd_pd) v(nd_out) v(nd_in)

+ v(nd_in_1) v(nd_out_of_in_1)

**********************************************************

* OUTPUT BUFFER

**********************************************************

b2 nd_pu nd_pd nd_out nd_in nd_pc nd_gc

+ file = '.ibis/at16245a.ibs'

+ model = 'AT16245_OUT'

**********************************************************

* TRANSMISSION LINE

**********************************************************

.PARAM Z_0=50

.PARAM T_delay=10ns

.PARAM Length=1mm

W1 N=1 nd_out GND nd_in_1 GND Umodel=Uname L=Length

.model Uname u nl=1 LEVEL=3 elev=3 llev=0 plev=1 nlay=2

+ zk=Z_0 delay=T_delay

**********************************************************

* INPUT BUFFER

**********************************************************

b1 nd_pc_1 nd_gc_1 nd_in_1 nd_out_of_in_1

+ file = '.ibis/at16245a.ibs'

+ model = 'AT16245_IN'

**********************************************************

.end