Field Solver Examples

The following example shows you how to use the Star-Hspice field solver. All the examples shown in this section are run with the HIGH accuracy mode and GRIDFACTOR = 1.

Example 1: Cylindrical Conductor Above a Ground Plane

In the first example, consider a copper cylindrical conductor above an ideal (lossless) ground plane. Cylindrical Conductor Above a Ground Plane shows the geometry. Input File Listing for Example 1 lists the corresponding Star-Hpsice netlist.

In this case, you can derive the exact analytical formulas for all of the transmission line parameters:1

Figure 18-13: Cylindrical Conductor Above a Ground Plane

 

 

Table 18-4: Input File Listing for Example 1

Header, options and sources

*Example 1: cylindrical conductor

.OPTION PROBE POST
VIMPULSE in1 gnd PULSE 4.82v 0v 5n 0.5n 0.5n 25n

W Element

W1 in1 gnd out1 gnd FSmodel=cir_trans N=1 l=0.5

Materials

.MATERIAL diel_1 DIELECTRIC ER=4,
+ LOSSTANGENT=1.2e-3
.MATERIAL copper METAL
+ CONDUCTIVITY=57.6meg

Shapes

.SHAPE circle_1 CIRCLE RADIUS=0.5mm

Defines a half-space

.LAYERSTACK halfSpace BACKGROUND=diel_1,
+ LAYER=(PEC,1mm)

Option settings

.FSOPTIONS opt1 PRINTDATA=YES,
+ COMPUTERS=yes, COMPUTEGD=yes

Model definition

.MODEL cir_trans W MODELTYPE=FieldSolver
+ LAYERSTACK=halfSpace, FSOPTIONS=opt1,
+ RLGCFILE=ex1.rlgc
+ CONDUCTOR=(SHAPE=circle_1,
+ ORIGIN=(0,4mm), MATERIAL=copper)

Analysis, outputs and end

.TRAN 0.5n 100n
.PROBE v(out1)
.END

 

 

 

Compare the computed results with the analytical solutions in Comparison Result for Example 1. The resistance and conductance are computed at the frequency of 200 MHz, and the DC resistance (R0) and conductance (G0) are not included in the computed values.

Table 18-5: Comparison Result for Example 1

Value

Exact

Computed

C (pF/m)

89.81

89.66

L (nH/m)

494.9

495.7

G (mS/m)

0.1354

0.1352

R ( /m)

1.194

1.178

Example 2: Stratified Dielectric Media

 

Figure 18-14: Three Traces Immersed in Stratified Dielectric Media

Three Traces Immersed in Stratified Dielectric Media shows an example of three traces immersed in stratified dielectric media. The input file listing is shown in Input File Listing for Example 2.

Comparison Result for Example 2 compares the computed capacitance matrix with results from two other numerical methods.

Table 18-6: Input File Listing for Example 2

Header, options and sources

*Example 2, three traces in dielectric

.OPTION PROBE POST
+ VIMPULSE in1 gnd PULSE 4.82v 0v 5n 0.5n 0.5n
+ 25n

W Element

W1 in1 in2 in3 gnd out1 out2 out3 gnd
+ FSmodel=cond3_sys N=3 l=0.5

Materials

.MATERIAL diel_1 DIELECTRIC ER=4.3
.MATERIAL diel_2 DIELECTRIC ER=3.2

Shapes

.SHAPE rect_1 RECTANGLE WIDTH=0.35mm,
+ HEIGHT=0.07mm

Uses the default AIR background

.LAYERSTACK stack_1
+ LAYER=(PEC,1um),LAYER=(diel_1,0.2mm),
+ LAYER=(diel_2,0.1mm)

Option settings

.FSOPTIONS opt1 PRINTDATA=YES

Three conductors share the same shape

.MODEL cond3_sys W MODELTYPE=FieldSolver,
+ LAYERSTACK=stack1, FSOPTIONS=opt1,
+ RLGCFILE=ex2.rlgc
+ CONDUCTOR=(SHAPE=rect_1,ORIGIN=
+ (0,0.201mm)),
+ CONDUCTOR=(SHAPE=rect_1,
+ ORIGIN=(0.5mm,0.301mm)),
+ CONDUCTOR=(SHAPE=rect_1,ORIGIN=
+ (1mm,0.301mm))

Analysis, outputs and end

.TRAN 0.5n 100n
.PROBE v(out1)
.END
Table 18-7: Comparison Result for Example 2

Computed

(pF/m)

Raphael
(Finite-Difference Solver)

(pF/m)

Reference2

(pF/m)

 

 

 

 

Convergence of Accuracy Modes shows the results of convergence analysis performed based on the total capacitance of the first conductor with respect to the GRIDFACTOR parameter.

Figure 18-15: Convergence of Accuracy Modes

Example 3: Two Traces Between Two Ground Planes

The following example uses the coupled strip line case shown in Two Traces Between Two Ground Planes. Input File Listing for Example 3 lists the complete input netlist. Comparison Result for Example 3 shows the comparison between the computed result and the Finite Element (FEM) solver result.

Figure 18-16: Two Traces Between Two Ground Planes
Table 18-8: Input File Listing for Example 3

Header, options and sources

*Example 3: two traces between gnd planes

.OPTION PROBE POST
+ IMPULSE in1 gnd PULSE 4.82v 0v 5n 0.5n 0.5n
+ 25n

W Element

W1 in1 in2 gnd out1 out2 gnd FSmodel=cond2_sys
+N=2 l=0.5

Materials

.MATERIAL diel_1 DIELECTRIC ER=10.0
.MATERIAL diel_2 DIELECTRIC ER=2.5

Shapes

.SHAPE rect RECTANGLE WIDTH=1mm,
+ HEIGHT=0.2mm,

Top and bottom ground planes

.LAYERSTACK stack_1,
+ LAYER=(PEC,1mm), LAYER=(diel_1,2mm),
+ LAYER=(diel_2,3mm), LAYER=(PEC,1mm)

Option settings

.FSOPTIONS opt1 PRINTDATA=YES

Two conductors share the same shape

.MODEL cond2_sys W MODELTYPE=FieldSolver,
+ LAYERSTACK=stack1, FSOPTIONS=opt1
+ RLGCFILE=ex3.rlgc
+ CONDUCTOR=(SHAPE=rect, ORIGIN=
+ (0,3mm)),
+ CONDUCTOR=(SHAPE=rect,
+ ORIGIN=(1.2mm,3mm))

Analysis, outputs and end

.TRAN 0.5n 100n
.PROBE v(out1)
.END
Table 18-9: Comparison Result for Example 3

Computed

(pF/m)

FEM Solver

(pF/m)

Example 4: Using Field Solver with Monte Carlo Analysis

The following example shows how to perform transient analysis using Monte Carlo analysis to model variations in the manufacturing of the microstrip. Input File Listing for Example 4 shows the Star-Hspice input listing with the W Element. Monte Carlo Analysis with a Field Solver and W Element shows the transient output waveforms.

 

Figure 18-17: Monte Carlo Analysis with a Field Solver and W Element
Table 18-10: Input File Listing for Example 4

Header, options and sources

*PETL Example 4: example 2 with Monte-Carlo

.OPTION PROBE POST
+ VIMPULSE in1 gnd AC=1v PULSE 4.82v 0v 5ns
+ 0.5ns 0.5ns 25ns

Parameter definitions

.PARAM x1=Gauss(0,0.02,1)
+ x2=Gauss(0.5mm,0.02,1) x3=Gauss(1mm,0.02,1)
.PARAM dRef=1u dY1=Gauss(2mm,0.02,1)
+ dY2=Gauss(1mm,0.02,1)

W Element

W1 in1 in2 in3 0 out1 out2 out3 0
+ FSMODEL=cond3_sys N=3 l=0.5

Materials

.MATERIAL diel_1 DIELECTRIC ER=4.3
.MATERIAL diel_2 DIELECTRIC ER=3.2

Shapes

.SHAPE r1 RECTANGLE WIDTH=0.35mm,
+ HEIGHT=0.070mm

Uses the default AIR background

.LAYERSTACK stack_1
+ LAYER= (PEC,dRef),LAYER=(diel_1,dY1),
+ LAYER= (diel_2,dY2)

Three conductors share the same shape

.MODEL cond3_sys W MODELTYPE=FieldSolver,
+ LAYERSTACK=stack1,
+ CONDUCTOR=(SHAPE=r1,ORIGIN=
+ (x1,`dRef+dY1')),
+ CONDUCTOR=(SHAPE=r1,ORIGIN=
+ (x2,`dRef+dY1+dY2')),
+ CONDUCTOR=(SHAPE=r1,ORIGIN=
+ (x3,`dRef+dY1+dY2'))

Analysis, outputs and end

.PROBE TRAN v(in1) v(out1) v(in3)
.PROBE AC v(out1) v(out3)
.PROBE DC v(in1) v(out1) v(out3)
.AC LIN 200 0Hz 0.3GHz
.DC v1 0v 5v 0.01v
.TRAN 0.5ns 100ns SWEEP MONTE=3
.END

 

 

1. S. Ramo, J. R. Whinnery, and T. V. Duzer, Fields and Waves in Communication Electronics, 2nd ed. New York: Wiley, 1984.

2. W. Delbare and D. D. Zutter, "Space-domain Green's function approach to the capacitance calculation of multiconductor lines in multilayered dielectrics with improved surface charge modeling," IEEE Trans. Microwave Theory and Tech., vol. 37, pp. 1562-1568, October 1989.

Star-Hspice Manual - Release 2001.2 - June 2001