Selecting Models

A MOS transistor is described by use of an element statement and a .MODEL statement.

The element statement defines the connectivity of the transistor and references the .MODEL statement. The .MODEL statement specifies either an n- or p-channel device, the level of the model, and a number of user-selectable model parameters.

Example

The following example specifies a PMOS MOSFET with a model reference name, PCH. The transistor is modeled using the LEVEL 13 BSIM model. The parameters are selected from the model parameter lists in this chapter.

M3 3 2 1 0 PCH <parameters>
.MODEL PCH PMOS LEVEL=13 <parameters>

Selecting MOSFET Model LEVELs

MOSFET models consist of client private and public models selected by the parameter .MODEL statement LEVEL parameter. New models are constantly being added to Star-Hspice.

Not all MOSFET models are available in the PC version of Star-Hspice. The following table shows what is available for PC users. Models listed are either on all platforms, including PC, as indicated in the third column, or they are available on all platforms except the PC, as indicated in the last column.

Selecting MOSFET Capacitors

The MOSFET capacitance model parameter, CAPOP, is associated with the MOS model. Depending on the value of CAPOP, different capacitor models are used to model the MOS gate capacitance, that is, the gate-to-drain capacitance, the gate-to-source capacitance, and the gate-to-bulk capacitance. CAPOP allows for the selection of several versions of the Meyer and charge conservation model.

Some of the capacitor models are tied to specific DC models; they are stated as such. Others are for general use by any DC model.

CAPOP=4 selects the recommended charge-conserving model (from among CAPOP=11, 12, or 13) for the given DC model.

LEVELs 49 and 53 use the Berkeley capacitance-model parameter CAPMOD. The proprietary models, as well as LEVELs 5, 17, 21, 22, 25, 27, 31, 33, 49, 53, 55, and 58 have their own built-in capacitance routines.

Selecting MOS Diodes

The model parameter ACM (Area Calculation Method), which controls the geometry of the source and drain diffusions, selects the modeling of the bulk-to-source and bulk-to-drain diodes of the MOSFET model. The diode model includes the diffusion resistance, capacitance, and DC currents to the substrate.

Searching Models as Function of W, L

Model parameters are often the same for MOSFETs having width and length dimensions within specific ranges. To take advantage of this, create a MOSFET model for a specific range of width and length. Star-Hspice uses these MOSFET model parameters to select the appropriate model for the given width and length.

The Star-Hspice automatic model selection program searches a data file for a MOSFET model with the width and length range specified in the MOSFET element statement. This model statement is then used in the simulation.

To search a data file for MOSFET models within a given range of width and length, provide a root extension for the model reference name (in the .MODEL statement). Also, use the model geometric range parameters LMIN, LMAX, WMIN, and WMAX. These model parameters give the range of the physical length and width dimensions to which the MOSFET model applies. For example, if the model reference name in the element statement is NCH, the model selection program examines the models with the same root model reference name NCH such as NCH.1, NCH.2 or NCH.A. The model selection program selects the first MOSFET model statement whose geometric range parameters include the width and length specified in the associated MOSFET element statement.

The following example shows how to call the MOSFET model selection program from a data file. The model selector program examines the .MODEL statements that have the model reference names with root extensions NCHAN.2, NCHAN.3, NCHY.20, and NCHY.50.

Example

*FILE: SELECTOR.SP TEST OF MOS MODEL SELECTOR

.OPTION LIST WL SCALE=1U SCALM=1U NOMOD

.OP

V1 1 0 5

V2 2 0 4

V3 3 0 1

V4 4 0 -1

M1 1 2 3 4 NCHAN 10 2

M2 1 2 3 4 NCHAN 10 3

M3 1 2 3 4 NCH 10 4

M4 1 2 3 4 NCHX 10 5

M5 1 2 3 4 NCHY 20 5

M6 1 2 3 4 NCHY 50 5

$$$$$$$ FOR CHANNEL LENGTH SELECTION

.MODEL NCHAN.2 NMOS LEVEL=2 VTO=2.0 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

+ LMIN=1 LMAX=2.5 WMIN=2 WMAX=15

.MODEL NCHAN.3 NMOS LEVEL=2 VTO=2.2 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

+ LMIN=2.5 LMAX=3.5 WMIN=2 WMAX=15

$$$$$$$ NO SELECTION FOR CHANNEL LENGTH AND WIDTH

.MODEL NCH NMOS LEVEL=2 VTO=2.3 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

$+ LMIN=3.5 LMAX=4.5 WMIN=2 WMAX=15

.MODEL NCHX NMOS LEVEL=2 VTO=2.4 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

$+ LMIN=4.5 LMAX=100 WMIN=2 WMAX=15

$$$$$$$ FOR CHANNEL WIDTH SELECTION

.MODEL NCHY.20 NMOS LEVEL=2 VTO=2.5 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

+ LMIN=4.5 LMAX=100 WMIN=15 WMAX=30

.MODEL NCHY.50 NMOS LEVEL=2 VTO=2.5 UO=800 TOX=500 NSUB=1E15

+ RD=10 RS=10 CAPOP=5

+ LMIN=4.5 LMAX=100 WMIN=30 WMAX=500

.END

Setting MOSFET Control Options

Specific control options (set in the .OPTIONS statement) used for MOSFET models include the following. For flag-type options, 0 is unset (off) and 1 is set (on).

Override the defaults DEFAD, DEFAS, DEFL, DEFNRD, DEFNRS, DEFPD, DEFPS, and DEFW in the MOSFET element statement by specifying AD, AS, L, NRD, NRS, PD, PS, and W, respectively.

Scaling Units

Units are controlled by the options SCALE and SCALM. SCALE scales element statement parameters, and SCALM scales model statement parameters. SCALM also affects the MOSFET gate capacitance and diode model parameters. In this chapter, scaling applies only to those parameters specified as scaled. If SCALM is specified as a parameter in a .MODEL statement, it overrides the option SCALM. In this way, models using different values of SCALM can be used in the same simulation. MOSFET parameter scaling follows the same rules as for other model parameters, for example:

Override global model size scaling for individual MOSFET, diode, and BJT models that uses the .OPTION SCALM=<val> statement by including SCALM=<val> in the .MODEL statement. .OPTION SCALM=<val> applies globally for JFETs, resistors, transmission lines, and all models other than MOSFET, diode, and BJT models, and cannot be overridden in the model.

Scaling for LEVEL 25 and 33

When using the proprietary LEVEL 25 (Rutherford CASMOS) or LEVEL 33 (National) models, the SCALE and SCALM options are automatically set to 1e-6. If you use these models together with other scalable models, however, set the options, SCALE=1e-6 and SCALM=1e-6, explicitly.

Bypassing Latent Devices

Use the BYPASS (latency) option to decrease simulation time in large designs. It speeds simulation time by not recalculating currents, capacitances, and conductances if the voltages at the terminal device nodes have not changed. The BYPASS option applies to MOSFETs, MESFETs, JFETs, BJTs, and diodes. Use .OPTION BYPASS to set BYPASS.

BYPASS can result in a reduction in accuracy of the simulation for tightly coupled circuits such as op-amps, high gain ring oscillators, and so on. Use .OPTION MBYPAS to set MBYPAS to a smaller value to improve the accuracy of the results.